[CG/Unity] Diffuse Warping

Warped Diffuse 기법은 가볍고도 응용이 편리해서 지금도 많이 사용되는 기법이다. 이 기법의 핵심 구현 기법은 빛 계산으로 쓰는 공식인 노멀과 라이트 벡터의 내적을 UV로 이용한다는 것이다.

Shader "Custom/NewSurfaceShader"
{
    Properties
    {
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _RampTex ("RampTex", 2D) = "white" {}
    }

    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Warp noambient

        #pragma target 3.0

        sampler2D _MainTex;
        sampler2D _RampTex;

        struct Input
        {
            float2 uv_MainTex;
        };

        void surf (Input IN, inout SurfaceOutput o)
        {
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex);
            o.Albedo = c.rgb;
            o.Alpha = c.a;
        }

        float4 LightingWarp(SurfaceOutput s, float3 lightDir, float atten){
            // float ndotl = dot(s.Normal, lightDir) * 0.5 + 0.5;
            float ndotl = (dot(s.Normal, lightDir) + 1) * 0.5;

            float4 ramp = tex2D(_RampTex, float2(ndotl, 0.5));

            return ramp;
        }

        ENDCG

    }
    FallBack "Diffuse"
}

그라데이션 텍스처

내적의 값을 UV로 사용하여 그라데이션 텍스처를 입힌 결과

이 방식의 장점은, 사용하는 Ramp 텍스처에 따라서 PR(Picture Reality) 렌더링과 NPR(Non-Picture Reality) 렌더링을 아우르는 다양한 효과를 모두 낼 수 있다는 것이다.

빛과 정반대로 반응하는 셰이더를 만들 수도 있으며, Half-Lamber를 직접 그리거나, 전혀 존재하지 않는 역광을 그려 넣을 수도 있다. 으용 방식은 무궁무진하다. 

또는 빛이 어둡게 넘어가는 중간 부분에 붉은 색을 강제로 칠해줌으로써 매우 간단한 가짜 피부의 SSS(Subsurface-Scattering) 효과를 만들어 줄 수도 있다.

 

pow 연산 함수는 조금 무거운 편이므로 모바일에서는 사용을 자제하는 것이 좋다.

 

이번에는 아래의 검은 줄이 N . L 즉, Lambert 연산의 밝기에 따라서 두께에 변화가 생긴다. 이는 '밝은 부분에는 외곽선이 얇아지고 어두운 부분에는 외곽선이 두꺼워진다.' 는 의미이다.

결과는 다음과 같이 텍스처 한 장에 무려 3가지의 효과가 들어간 것과 같은 효과를 볼 수 있게 된다. 참고로 이러한 기법은 PBR 구현을 위한 살사체 텍스쳐와는 잘 어울리지 않는다. 단순한 색감의 만화 케릭터 텍스처가 더 어울릴 것이다.

Shader "Custom/NewSurfaceShader"
{
    Properties
    {
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _BumpMap ("NormalMap", 2D) = "bump" {}
        _RampTex ("RampTex", 2D) = "white" {}
    }

    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        #pragma surface surf Warp noambient

        #pragma target 3.0

        sampler2D _MainTex;
        sampler2D _BumpMap;
        sampler2D _RampTex;

        struct Input
        {
            float2 uv_MainTex;
            float2 uv_BumpMap;
        };

        void surf (Input IN, inout SurfaceOutput o)
        {
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex);
            o.Normal = UnpackNormal(tex2D(_BumpMap, IN.uv_BumpMap));
            o.Albedo = c.rgb;
            o.Alpha = c.a;
        }

        float4 LightingWarp(SurfaceOutput s, float3 lightDir, float3 viewDir, float atten){
            float3 H = normalize(lightDir + viewDir);
            float spec = saturate(dot(s.Normal, H));
            // float ndotl = dot(s.Normal, lightDir) * 0.5 + 0.5;
            float ndotl = (dot(s.Normal, lightDir) + 1) * 0.5;
            float4 ramp = tex2D(_RampTex, float2(ndotl, spec));

            float4 final;
            // ramp 텍스처를 10% 정도 강하게
            final.rgb = s.Albedo.rgb * ramp.rgb + ramp.rgb * 0.1;
            final.a = s.Alpha;

            return final;
        }

        ENDCG

    }
    FallBack "Diffuse"
}