[CG/Unity] 2Pass를 이용한 깨끗한 알파 블랜딩

알파 블랜딩을 사용하면 반대쪽 팔이 안으로 들어오고, 앞뒤 판정이 이상해지면서 좋지 않은 결과를 얻는다. 이것을 해결하는 방법 중 하나는 2Pass를 이용하는 것이다.

원리는 간단하다. 첫 번째 패스는 z 버퍼에는 그리되 화면에는 그리지 않는 것이다. 즉, z 버퍼에만 그리는 패스를 만든다. 이 코드는 모든 variants를 최소한으로 줄이고, 최대한 계산을 줄여서 만든 셰이더이다.

ColorMask 0 명령은 화면에 이 셰이더의 결과물을 보이지 않도록 만든다. 아예 투명으로 만들어도 된다만, fog 등 예상치 못한 외부의 결과물에 대한 대비책이다.

그리고 두 번째 패스에서 z 버퍼를 쓰지 않고 그린다. 평범한 반투명이다. 그러면 이미 존재하던 z 버퍼에 가려진 부분은 그려지지 않게 될테니 깨끗한 반투명이 만들어진다.

Shader "Custom/Alpha2Pass"
{
    Properties
    {
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200

        zwrite on
        ColorMask 0

        CGPROGRAM
        #pragma surface surf nolight noambient noforwardadd nolightmap novertexlights noshadow

        #pragma target 3.0

        struct Input
        {
            float4 color:COLOR; 
        };

        void surf (Input IN, inout SurfaceOutput o)
        {
        }

        float4 Lightingnolight(SurfaceOutput s, float3 lightDir, float atten){
            return float4(0, 0, 0, 0);
        }
        ENDCG

        // 2nd pass zwrite off, rendering on
        zwrite off

        CGPROGRAM
        #pragma surface surf Lambert alpha:fade

        sampler2D _MainTex;

        struct Input
        {
            float2 uv_MainTex;
        };

        void surf (Input IN, inout SurfaceOutput o)
        {
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex);
            o.Albedo = c.rgb;
            o.Alpha = 0.5;
        }
        ENDCG

    }
    FallBack "Diffuse"
}

이렇게하면 뒷면이 비쳐 보이지 않는 깨끗한 반투명이 완성되었다. 머리카락을 알파 브랜딩으로 표현할 때도 사용할 수 있는 방법이다.